Реклама на этом месте
Форум 1С
Форум 1С
Программистам. Бухгалтерам. Администраторам. Пользователям
Задай вопрос - получи решение проблемы. Без троллинга и флуда.
11 Дек 2017, 18:30
МультиВход
Добро пожаловать, Гость. Пожалуйста, войдите или зарегистрируйтесь.
Не получили письмо с кодом активации?
 
collapse

Автор Тема: Как реализовать группировку с расшифровкой?  (Прочитано 3337 раз)

0 Пользователей и 1 Гость просматривают эту тему.

Оффлайн sapravka

  • *
  • Сообщений: 40
  • РЕПУТАЦИЯ: 1
  • КПД: 3%
  • Регистрация: 2011-09-27
  • Сайт: волгалаб.рф
  • Профессия: Ученик 1С
 Здравствуйте!
Собственное все по порядку!
Имеется документ Отчет производства за смену в конфигурации бухгалтерия предприятия 2.0
В нем на закладке продукция, заполняем блюда:

А на закладке материалы автоматический заполняется материалы, из чего собственно и создана данная продукции:

В модуле объекта документа прописал следующее:
Функция ПечатьКанкуляционнаяКарта()

Запрос = Новый Запрос;
Запрос.УстановитьПараметр("ТекущийДокумент", ЭтотОбъект.Ссылка);
Запрос.Текст =
"ВЫБРАТЬ
| ОтчетПроизводстваЗаСменуПродукция.Номенклатура.ОсновнаяСпецификацияНоменклатуры.Владелец.Ссылка КАК Блюда,
| ОтчетПроизводстваЗаСменуПродукция.Количество КАК КоличествоБлюд,
| СпецификацииНоменклатурыИсходныеКомплектующие.Номенклатура КАК Индигриенты,
| СпецификацииНоменклатурыИсходныеКомплектующие.Количество КАК КоличествоНаОдноБлюдо,
| ОтчетПроизводстваЗаСменуПродукция.Количество * СпецификацииНоменклатурыИсходныеКомплектующие.Количество КАК ОбщееКоличество,
| ОтчетПроизводстваЗаСмену.Номер КАК Номер,
| ОтчетПроизводстваЗаСмену.Дата КАК Дата,
| ОтчетПроизводстваЗаСмену.Склад КАК Склад
|ИЗ
| Документ.ОтчетПроизводстваЗаСмену.Продукция КАК ОтчетПроизводстваЗаСменуПродукция
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.СпецификацииНоменклатуры.ИсходныеКомплектующие КАК СпецификацииНоменклатурыИсходныеКомплектующие
| ПО ОтчетПроизводстваЗаСменуПродукция.Номенклатура = СпецификацииНоменклатурыИсходныеКомплектующие.Ссылка.Владелец
| ЛЕВОЕ СОЕДИНЕНИЕ Документ.ОтчетПроизводстваЗаСмену КАК ОтчетПроизводстваЗаСмену
| ПО ОтчетПроизводстваЗаСменуПродукция.Ссылка = ОтчетПроизводстваЗаСмену.Ссылка
|ГДЕ
| ОтчетПроизводстваЗаСменуПродукция.Ссылка = &ТекущийДокумент
|ИТОГИ ПО
| ОБЩИЕ";


//ЗапросСтрока = Запрос.Выполнить().Выгрузить();

Запрос.УстановитьПараметр("ОтчетПроизводстваЗаСменуПродукция.Ссылка", Ссылка);
  Выборка = Запрос.Выполнить().Выбрать();
  Выборка.Следующий();

Макет = ПолучитьМакет("Калькуляция");




// Выводим все доступные областя макета
ОбластьШапка   = Макет.ПолучитьОбласть("Шапка");
ОбластьБлюда   = Макет.ПолучитьОбласть("Блюда");
ОбластьСтрока = Макет.ПолучитьОбласть("Строка");
ОбластьПодвал  = Макет.ПолучитьОбласть("Подвал");

ТабДокумент = Новый ТабличныйДокумент;

// Загрузим настройки пользователя.
ТабДокумент.ИмяПараметровПечати = "ПАРАМЕТРЫ_ПЕЧАТИ_Калькуляция";


// Выводим Шапку


Результат = Запрос.Выполнить();   
Выборка = Результат.Выбрать();
//не выводяться почемуто данные...
ОбластьШапка.Параметры.Номер = Выборка.Номер;
ОбластьШапка.Параметры.Дата = Выборка.Дата;
ОбластьШапка.Параметры.Склад = Выборка.Склад;
//хотя сама шапка выводиться
        ТабДокумент.Вывести(ОбластьШапка);



Пока Выборка.Следующий() Цикл
ОбластьБлюда.Параметры.Блюда = Выборка.Блюда;
            ТабДокумент.Вывести(ОбластьБлюда);
ОбластьСтрока.Параметры.СоставБлюд = Выборка.Индигриенты;
ОбластьСтрока.Параметры.ОбщееКоличество = Выборка.ОбщееКоличество;
ТабДокумент.Вывести(ОбластьСтрока); 
КонецЦикла;

 
Область = Макет.ПолучитьОбласть("Подвал");
ТабДокумент.Вывести(Область);


    ТабДокумент.Показать();
 
КонецФункции // ПечатьКанкуляционнаяКарта()

А в макете следующее:

И при печати выходит следующее:

 
Подскажите, пожалуйста, как сделать так, чтобы в печатной форме происходила группировка по продукции, вот так:
 
То есть что бы сначала шла продукция, а потом, то что входит в её состав и соответственно считалась сумма продукции(складывалась сумма всех составляющих её материалов).
Мысль у меня была такая: Сначала что бы выводил область блюда, а потом область строка (то есть из чего состоит) – но вот что то не могу понять, как это реализовать... Как это прописать в модуле объекта? (да и в верху три лишних колонки почему то получается, хотя в макете нет никаких пропусков)
И еще – в шапке, почему то не выводит номер и дату документа, хотя вроде бы прописал все и в параметрах и в самом модуле объекта?


Оффлайн Yura063

  • *****
  • Сообщений: 1045
  • РЕПУТАЦИЯ: 136
  • КПД: 13%
  • Регистрация: 2010-11-15
  • Сайт: yuis.ru
  • Профессия: Программист 1С
Сделайте так:
Блюдо1="";
Пока Выборка.Следующий() Цикл
     Если Блюдо1 = Выборка.Блюда Тогда
            ОбластьСтрока.Параметры.СоставБлюд = Выборка.Индигриенты;
            ОбластьСтрока.Параметры.ОбщееКоличество = Выборка.ОбщееКоличество;
            ТабДокумент.Вывести(ОбластьСтрока);
    Иначе
            Блюда1 = Выборка.Блюда;
            ОбластьБлюда.Параметры.Блюда = Выборка.Блюда;
            ТабДокумент.Вывести(ОбластьБлюда);
    КонецЕсли;
КонецЦикла;
Помогли, отблагодари!

Оффлайн sapravka

  • *
  • Сообщений: 40
  • РЕПУТАЦИЯ: 1
  • КПД: 3%
  • Регистрация: 2011-09-27
  • Сайт: волгалаб.рф
  • Профессия: Ученик 1С
Сделайте так:
Блюдо1="";
Пока Выборка.Следующий() Цикл
     Если Блюдо1 = Выборка.Блюда Тогда
            ОбластьСтрока.Параметры.СоставБлюд = Выборка.Индигриенты;
            ОбластьСтрока.Параметры.ОбщееКоличество = Выборка.ОбщееКоличество;
            ТабДокумент.Вывести(ОбластьСтрока);
    Иначе
            Блюда1 = Выборка.Блюда;
            ОбластьБлюда.Параметры.Блюда = Выборка.Блюда;
            ТабДокумент.Вывести(ОбластьБлюда);
    КонецЕсли;
КонецЦикла;

Спасибо!
Сейчас попробую...
А не подскажите, как в запросе сделать итоги по блюдам (продукции)?

Оффлайн sertak

  • ****
  • Сообщений: 274
  • РЕПУТАЦИЯ: 74
  • КПД: 27%
  • Регистрация: 2013-01-16
    • Skype: vitaly_sertakov
  • Сайт: www.sertakov.ru
  • Профессия: Программист 1С
Результат = Запрос.Выполнить();   
 Выборка = Результат.Выбрать();
//не выводяться почемуто данные...
ОбластьШапка.Параметры.Номер = Выборка.Номер;
ОбластьШапка.Параметры.Дата = Выборка.Дата;
ОбластьШапка.Параметры.Склад = Выборка.Склад;
//хотя сама шапка выводиться       
 ТабДокумент.Вывести(ОбластьШапка);
Для того, чтобы в шапке отобразились значения из выборки, шапку необходимо вывести внутри цикла (ведь до цикла мы не позиционировались ни на одной строке, соответственно откуда бы взяться, например, значению Выборка.Склад), но для того, чтобы шапка вывелась только 1 раз, можно добавить флаг, например ПерваяИтерация, проверять его и сбрасывать после первой итерации. Например:
Результат = Запрос.Выполнить();   
Выборка = Результат.Выбрать();
ПерваяИтерация = Истина;
Пока Выборка.Следующий() Цикл
    Если ПерваяИтерация Тогда
        ОбластьШапка.Параметры.Номер = Выборка.Номер;
        ОбластьШапка.Параметры.Дата = Выборка.Дата;
        ОбластьШапка.Параметры.Склад = Выборка.Склад;
        ТабДокумент.Вывести(ОбластьШапка);
        ПерваяИтерация = Ложь;
    КонецЕсли;
    ...
Добавлено: 20 Янв 2013, 18:13

  
        |ВЫБРАТЬ
| ОтчетПроизводстваЗаСменуПродукция.Номенклатура КАК Блюда,
| СуммыПоБлюдам.СуммаПоОдномуБлюду КАК СуммаВсехИнгредиентовПоОдномуБлюду,
| ОтчетПроизводстваЗаСменуПродукция.Количество КАК КоличествоБлюд,
| СуммыПоБлюдам.СуммаПоОдномуБлюду * ОтчетПроизводстваЗаСменуПродукция.Количество КАК СуммаВсехИнгредиентовПоОдномуБлюдуЗаСмену,
| СпецификацииНоменклатурыИсходныеКомплектующие.Номенклатура КАК Индигриенты,
| СпецификацииНоменклатурыИсходныеКомплектующие.Количество КАК КоличествоНаОдноБлюдо,
| ОтчетПроизводстваЗаСменуПродукция.Количество * СпецификацииНоменклатурыИсходныеКомплектующие.Количество КАК ОбщееКоличество,
| ОтчетПроизводстваЗаСменуПродукция.Ссылка.Номер КАК Номер,
| ОтчетПроизводстваЗаСменуПродукция.Ссылка.Дата КАК Дата,
| ОтчетПроизводстваЗаСменуПродукция.Ссылка.Склад КАК Склад
|ИЗ
| Документ.ОтчетПроизводстваЗаСмену.Продукция КАК ОтчетПроизводстваЗаСменуПродукция
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.СпецификацииНоменклатуры.ИсходныеКомплектующие КАК СпецификацииНоменклатурыИсходныеКомплектующие
| ПО ОтчетПроизводстваЗаСменуПродукция.Номенклатура = СпецификацииНоменклатурыИсходныеКомплектующие.Ссылка.Владелец
| ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
| ОтчетПроизводстваЗаСменуПродукция.Номенклатура КАК Блюдо,
| СУММА(СпецификацииНоменклатурыИсходныеКомплектующие.Количество) КАК СуммаПоОдномуБлюду
| ИЗ
| Документ.ОтчетПроизводстваЗаСмену.Продукция КАК ОтчетПроизводстваЗаСменуПродукция
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.СпецификацииНоменклатуры.ИсходныеКомплектующие КАК СпецификацииНоменклатурыИсходныеКомплектующие
| ПО ОтчетПроизводстваЗаСменуПродукция.Номенклатура = СпецификацииНоменклатурыИсходныеКомплектующие.Ссылка.Владелец
| ГДЕ
| ОтчетПроизводстваЗаСменуПродукция.Ссылка = &ТекущийДокумент |
| СГРУППИРОВАТЬ ПО
| ОтчетПроизводстваЗаСменуПродукция.Номенклатура) КАК СуммыПоБлюдам
| ПО ОтчетПроизводстваЗаСменуПродукция.Номенклатура = СуммыПоБлюдам.Блюдо
|ГДЕ
| ОтчетПроизводстваЗаСменуПродукция.Ссылка = &ТекущийДокумент
Думаю, из псевдонимов полей будет ясно их содержание.
Если ты знаешь свой путь, то удачи и неудачи равно продвигают тебя вперед

Последний раз редактировалось: sertak; 20 Янв 2013, 18:13

Оффлайн sapravka

  • *
  • Сообщений: 40
  • РЕПУТАЦИЯ: 1
  • КПД: 3%
  • Регистрация: 2011-09-27
  • Сайт: волгалаб.рф
  • Профессия: Ученик 1С
Попробывал сделать так:
Сделайте так:
Блюдо1="";
Пока Выборка.Следующий() Цикл
     Если Блюдо1 = Выборка.Блюда Тогда
            ОбластьСтрока.Параметры.СоставБлюд = Выборка.Индигриенты;
            ОбластьСтрока.Параметры.ОбщееКоличество = Выборка.ОбщееКоличество;
            ТабДокумент.Вывести(ОбластьСтрока);
    Иначе
            Блюда1 = Выборка.Блюда;
            ОбластьБлюда.Параметры.Блюда = Выборка.Блюда;
            ТабДокумент.Вывести(ОбластьБлюда);
    КонецЕсли;
КонецЦикла;
И получилось вот так:

Подскажите, пожалуйста, что необходимо поправить, что бы получилось вот так:

Оффлайн sertak

  • ****
  • Сообщений: 274
  • РЕПУТАЦИЯ: 74
  • КПД: 27%
  • Регистрация: 2013-01-16
    • Skype: vitaly_sertakov
  • Сайт: www.sertakov.ru
  • Профессия: Программист 1С
Вот запрос с суммами по блюду. Я не очень понимаю, какую именно сумму надо указать в поле макета СуммаБлюда, поэтому в запросе есть 2 поля: СуммаВсехИнгредиентовПоОдномуБлюду и СуммаВсехИнгредиентовПоОдномуБлюдуЗаСмену. Выберите нужное сами.
	|ВЫБРАТЬ
| ОтчетПроизводстваЗаСменуПродукция.Номенклатура КАК Блюда,
| СуммыПоБлюдам.СуммаПоОдномуБлюду КАК СуммаВсехИнгредиентовПоОдномуБлюду,
| ОтчетПроизводстваЗаСменуПродукция.Количество КАК КоличествоБлюд,
| СуммыПоБлюдам.СуммаПоОдномуБлюду * ОтчетПроизводстваЗаСменуПродукция.Количество КАК СуммаВсехИнгредиентовПоОдномуБлюдуЗаСмену,
| СпецификацииНоменклатурыИсходныеКомплектующие.Номенклатура КАК Ингредиенты,
| СпецификацииНоменклатурыИсходныеКомплектующие.Количество КАК КоличествоНаОдноБлюдо,
| ОтчетПроизводстваЗаСменуПродукция.Количество * СпецификацииНоменклатурыИсходныеКомплектующие.Количество КАК ОбщееКоличество,
| ОтчетПроизводстваЗаСменуПродукция.Ссылка.Номер КАК Номер,
| ОтчетПроизводстваЗаСменуПродукция.Ссылка.Дата КАК Дата,
| ОтчетПроизводстваЗаСменуПродукция.Ссылка.Склад КАК Склад
|ИЗ
| Документ.ОтчетПроизводстваЗаСмену.Продукция КАК ОтчетПроизводстваЗаСменуПродукция
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.СпецификацииНоменклатуры.ИсходныеКомплектующие КАК СпецификацииНоменклатурыИсходныеКомплектующие
| ПО ОтчетПроизводстваЗаСменуПродукция.Номенклатура = СпецификацииНоменклатурыИсходныеКомплектующие.Ссылка.Владелец
| ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
| ОтчетПроизводстваЗаСменуПродукция.Номенклатура КАК Блюдо,
| СУММА(СпецификацииНоменклатурыИсходныеКомплектующие.Количество) КАК СуммаПоОдномуБлюду
| ИЗ
| Документ.ОтчетПроизводстваЗаСмену.Продукция КАК ОтчетПроизводстваЗаСменуПродукция
| ЛЕВОЕ СОЕДИНЕНИЕ Справочник.СпецификацииНоменклатуры.ИсходныеКомплектующие КАК СпецификацииНоменклатурыИсходныеКомплектующие
| ПО ОтчетПроизводстваЗаСменуПродукция.Номенклатура = СпецификацииНоменклатурыИсходныеКомплектующие.Ссылка.Владелец
| ГДЕ
        |                    ОтчетПроизводстваЗаСменуПродукция.Ссылка = &ТекущийДокумент
| СГРУППИРОВАТЬ ПО
        |                    ОтчетПроизводстваЗаСменуПродукция.Номенклатура) КАК СуммыПоБлюдам
| ПО ОтчетПроизводстваЗаСменуПродукция.Номенклатура = СуммыПоБлюдам.Блюдо
|ГДЕ
        |    ОтчетПроизводстваЗаСменуПродукция.Ссылка = &ТекущийДокумент
|
|УПОРЯДОЧИТЬ ПО
| Блюда,
| Ингредиенты

Добавлено: 21 Янв 2013, 10:00

И вариант вывода в макет, который вам приводили, немного дополнил:

Выборка = Запрос.Выполнить().Выбрать();
ТекущееБлюдо = Неопределено;
Пока Выборка.Следующий() Цикл
    Если ТекущееБлюдо = Выборка.Блюда Тогда
        ОбластьСтрока.Параметры.СоставБлюд = Выборка.Ингредиенты;
        ОбластьСтрока.Параметры.ОбщееКоличество = Выборка.ОбщееКоличество;
        ТабДокумент.Вывести(ОбластьСтрока);
    Иначе
        ТекущееБлюдо = Выборка.Блюда;
        ОбластьБлюда.Параметры.Блюда = Выборка.Блюда;   
        ОбластьБлюда.Параметры.СуммаБлюда = Выборка.СуммаВсехИнгредиентовПоОдномуБлюду;
        ТабДокумент.Вывести(ОбластьБлюда);
        ОбластьСтрока.Параметры.СоставБлюд = Выборка.Ингредиенты;   
        ОбластьСтрока.Параметры.ОбщееКоличество = Выборка.ОбщееКоличество;   
        ТабДокумент.Вывести(ОбластьСтрока);
    КонецЕсли;
КонецЦикла;
Если ты знаешь свой путь, то удачи и неудачи равно продвигают тебя вперед

Оффлайн Klyacksa

  • Фрилансер. Милости прошу с задачами в личку.
  • Глобальный модератор
  • *****
  • Сообщений: 1325
  • РЕПУТАЦИЯ: 430
  • КПД: 32%
  • Регистрация: 2010-08-20
  • Сайт: 
  • Профессия: Программист 1С
Зачем соединять еще и с самим документом по ссылке, если он у нас и так уже есть? К Номеру, Дате и Складу можно достучаться через Ссылку.
Итоги/группировки надо получать правильно, еще в запросе, а не отрабатывать потом "Если это все еще то же блюдо, тогда..."
Схема запроса такая:
	"ВЫБРАТЬ
|    ОтчетПроизводстваЗаСменуПродукция.Номенклатура КАК Блюда,
|    ОтчетПроизводстваЗаСменуПродукция.Количество КАК КоличествоБлюд,
|    СпецификацииНоменклатурыИсходныеКомплектующие.Номенклатура КАК Индигриенты,
|    СпецификацииНоменклатурыИсходныеКомплектующие.Количество КАК КоличествоНаОдноБлюдо,
|    ОтчетПроизводстваЗаСменуПродукция.Количество * СпецификацииНоменклатурыИсходныеКомплектующие.Количество КАК ОбщееКоличество,
|    ОтчетПроизводстваЗаСменуПродукция.Ссылка.Номер КАК Номер,
|    ОтчетПроизводстваЗаСменуПродукция.Ссылка.Дата КАК Дата,
|    ОтчетПроизводстваЗаСменуПродукция.Ссылка.Склад КАК Склад
|ИЗ
|    Документ.ОтчетПроизводстваЗаСмену.Продукция КАК ОтчетПроизводстваЗаСменуПродукция
|        ЛЕВОЕ СОЕДИНЕНИЕ Справочник.СпецификацииНоменклатуры.ИсходныеКомплектующие КАК СпецификацииНоменклатурыИсходныеКомплектующие
|        ПО ОтчетПроизводстваЗаСменуПродукция.Номенклатура = СпецификацииНоменклатурыИсходныеКомплектующие.Владелец
|ГДЕ
|    ОтчетПроизводстваЗаСменуПродукция.Ссылка = &ТекущийДокумент
|ИТОГИ
| МАКСИМУМ(КоличествоБлюд),
| МАКСИМУМ(КоличествоНаОдноБлюдо),
| МАКСИМУМ(ОбщееКоличество)
|ПО
|    Блюда";

Вывод в макет:
Выборка = Запрос.Выполнить().Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);
Пока Выборка.Следующий() Цикл
    ОбластьБлюда.Параметры.Заполнить(Выборка);
    ТабДокумент.Вывести(ОбластьБлюда);

    ВыборкаСтрока=Выборка.Выбрать();
    Пока ВыборкаСтрока.Следующий() цикл
        ОбластьСтрока.Параметры.Заполнить(ВыборкаСтрока);
        ТабДокумент.Вывести(ОбластьСтрока);
    КонецЦикла;
КонецЦикла;

Принцип вывода итогов такой, по цифровым колонкам посмотрите внимательно, что куда и как должно считаться/выводиться, сильно не вникала.
Примечание. Чтобы отрабатывал метод Заполнить, нужно чтобы имена полей и параметров совпадали, иначе придется руками прописывать, как во всех комментах выше.
xxx: Спасибо! Я бы загуглил, но ты интересней. Материшься. Злишься. Послать можешь...

Мысль - это оргазм мозга. Кто способен его испытать - получают истинное наслаждение, остальным приходится имитировать

Оффлайн Yura063

  • *****
  • Сообщений: 1045
  • РЕПУТАЦИЯ: 136
  • КПД: 13%
  • Регистрация: 2010-11-15
  • Сайт: yuis.ru
  • Профессия: Программист 1С
Цитировать
Блюда1="";
Пока Выборка.Следующий() Цикл
     Если Блюда1 = Выборка.Блюда Тогда
            ОбластьСтрока.Параметры.СоставБлюд = Выборка.Индигриенты;
            ОбластьСтрока.Параметры.ОбщееКоличество = Выборка.ОбщееКоличество;
            ТабДокумент.Вывести(ОбластьСтрока);
    Иначе
            Блюда1 = Выборка.Блюда;
            ОбластьБлюда.Параметры.Блюда = Выборка.Блюда;
            ТабДокумент.Вывести(ОбластьБлюда);
    КонецЕсли;
КонецЦикла;
Написал в спешки, совершил пару ошибок :btbzdb:! Вы хоть сами смотрите, а то копировали и все тут!
Помогли, отблагодари!


Теги:
 

Подскажите как реализовать "планинг"?

Автор cannabis_86Раздел Конфигурирование, программирование в "1С - Предприятие 8"

Ответов: 2
Просмотров: 2145
Последний ответ 20 Июн 2011, 10:29
от cska-fanat-kz
Система компоновки данных – как в макете реализовать сложение(вычитание) ячеек?

Автор sapravkaРаздел Конфигурирование, программирование в "1С - Предприятие 8"

Ответов: 3
Просмотров: 3765
Последний ответ 14 Фев 2013, 22:34
от sapravka
Запись клиентов на определенную дату-время: подскажите как реализовать?

Автор nst1Раздел Конфигурирование, программирование в "1С - Предприятие 8"

Ответов: 9
Просмотров: 662
Последний ответ 21 Июн 2017, 23:03
от oleg-x
Помогите чайнику, на чем лучше реализовать такую задачу?

Автор Sergey101Раздел Конфигурирование, программирование в "1С - Предприятие 8"

Ответов: 2
Просмотров: 1727
Последний ответ 27 Фев 2012, 17:38
от Sergey101
Список значений в поле ввода, как правильно реализовать?

Автор SJslavaРаздел Конфигурирование, программирование в "1С - Предприятие 8"

Ответов: 18
Просмотров: 10371
Последний ответ 17 Апр 2015, 17:22
от cska-fanat-kz

* Живое общение

Не устроил ответ?

Зарегистрируйся и задай свой вопрос. Живое общение приносит результат намного быстрее.


Зарегистрироваться

* Реклама

* Поиск

* Последние задачи на разработку (фриланс)

* Реклама

* Последние вакансии

* Топ 10 авторов за месяц

Геннадий ОбьГЭС Геннадий ОбьГЭС
163 Сообщений
ilyay ilyay
75 Сообщений
oleg-x
56 Сообщений
alex0402
46 Сообщений
andron81_81
44 Сообщений
AIFrame
35 Сообщений
MuI_I_Ika MuI_I_Ika
33 Сообщений
Golickoff Golickoff
28 Сообщений
BuhRust
27 Сообщений
Dima Dddd Dima Dddd
26 Сообщений

* Кто онлайн

  • Точка Гостей: 451
  • Точка Скрытых: 0
  • Точка Пользователей: 5
  • Точка Сейчас на форуме:

* Облако тэгов

* Форум 1С с мобильного

* Инструменты

* Дополнительно

Поиск

 
SimplePortal 2.3.5 © 2008-2012, SimplePortal