Реклама на этом месте
Форум 1С
Форум 1С
Программистам. Бухгалтерам. Администраторам. Пользователям
Задай вопрос - получи решение проблемы. Без троллинга и флуда.
19 Дек 2017, 01:34
МультиВход
Добро пожаловать, Гость. Пожалуйста, войдите или зарегистрируйтесь.
Не получили письмо с кодом активации?
 
collapse

Автор Тема: Работа с ТаблицейЗначений  (Прочитано 28152 раз)

0 Пользователей и 1 Гость просматривают эту тему.

Оффлайн Juli1000

  • *
  • Сообщений: 40
  • РЕПУТАЦИЯ: 2
  • КПД: 5%
  • Регистрация: 2009-07-03
  • Сайт: 
Всем, привет :)
Помогите пожалуйста, с возникшей проблемой.Есть ТаблицаЗначений1 и ТаблицаЗначений2. Они абсолютно одинаковы,отличаются только последней колонкой. Можно ли взять последнюю колонку из ТаблицаЗначений1 и прикрепить к ТаблицаЗначений2. Если можно, тогда как?
спасибо :)


Оффлайн DDD

  • ****
  • Сообщений: 374
  • РЕПУТАЦИЯ: 23
  • КПД: 6%
  • Регистрация: 2008-07-12
  • Сайт: 
Вот есть для начала небольшой фак - простые примеры работы с таблицей значений:


1. Создать таблицу значений

ТаблицаЗначений = Новый ТаблицаЗначений;

2. Создать колонки таблицы значений:

ТаблицаЗначений.Колонки.Добавить("Имя");
ТаблицаЗначений.Колонки.Добавить("Фамилия");

3. Добавить новые строки используя имена колонок:

НоваяСтрока = ТаблицаЗначений.Добавить();
НоваяСтрока.Имя = "Василий";
НоваяСтрока.Фамилия = "Пупкин";

4. Как искать значение в таблице значений:
Необходимо найти строку таблицы содержащую искомое значение.

НайденнаяСтрока = ТаблицаЗначений.Найти(ИскомоеЗначение);

5. Найти первое вхождение в определенных колонках таблицы значений

НайденнаяСтрока = ТаблицаЗначений.Найти(ИскомоеЗначение, "Поставщик, Покупатель");

6. Если надо найти все вхождения в таблице значений:
Используем структуру поиска.

СтруктураПоиска = Структура("Сотрудник", ИскомоеЗначение);
МассивНайденныхСтрок = ТаблицаЗначений.НайтиСтроки(СтруктураПоиска);

Создадим структуру поиска, каждый элемент которой будет содержать имя колонки в качестве ключа и искомое значение в этой колонке – в качестве значения. Передаем СтруктуруПоискав качестве параметра методу НайтиСтроки(). В результате получеем массив строк таблицы.
Если в структуру поиска добавить поиск нужного значения, например, еще и в колонке Ответственный, то в результате применения метода НайтиСтроки() получим все строки, где и Сотрудник, и Ответственный равны искомому значению.

7. Как перебрать таблицу значений в произвольном порядке

Для Каждого ТекущаяСтрока Из ТаблицаЗначений Цикл
Сообщить(ТекущаяСтрока.Имя);
КонецЦикла;


Тоже самое используя индексы:

СтаршийИндекс = ТаблицаЗначений.Количество() - 1;
Для Сч = 0 по СтаршийИндекс Цикл
Сообщить(ТаблицаЗначений[Сч].Имя);
КонецЦикла;

8. Удаление имеющейся строки таблицы значений

ТаблицаЗначений.Удалить(УдаляемаяСтрока); 


по индексу

ТаблицаЗначений.Удалить(0);

9. Удаление имеющейся колонки таблицы значений

ТаблицаЗначений.Колонки.Удалить(УдаляемаяКолонка);

по индексу

ТаблицаЗначений.Колонки.Удалить(0);

Необходимо учитывать, что удаление строки (или колонки) «из середины» таблицы значений приведет к уменьшению на единицу индексов строк, стоявших «после» удаленной

10. Как заполнить таблицу значений, если имена колонок содержатся в переменных?

НоваяСтрока = ТаблицаЗначений.Добавить();
НоваяСтрока[ИмяКолонки] = Значение;

11. Как заполнить всю колонку таблицы значений нужным значением?
Колонку ФлагФискальногоУчета в таблице значений ТаблицаЗначений необходимо заполнить значением Ложь

ТаблицаЗначений.ЗаполнитьЗначения(Ложь, "ФлагФискальногоУчета");

Применяем для таблицы значений метод ЗаполнитьЗначения(). Первым параметром передаем заполняемое значение. Вторым параметром – имя заполняемой колонки.

12. Как таблицу значений «ТаблицаПолучатель» заполнить данными таблицы значений «ИсходнаяТаблица»?

Если ТаблицаПолучатель на момент выполнения операции еще не существует или ее предыдущие колонки сохранять не нужно, можно создать ее как полную копию исходной

ТаблицаПолучатель = ТаблицаИсходная.Скопировать();

Вариант второй: таблица ТаблицаПолучатель существует, и жалко терять ее колонки и ограничения на типы данных колонок. Но нужно заполнить данные по колонкам, имена которых совпадают с именами исходной таблицы.

Частичный перенос данных для колонок с совпадающими именами:

Для Каждого СтрокаИсходнойТаблицы Из ИсходнаяТаблица Цикл
НоваяСтрока = ТаблицаПолучатель.Добавить();
ЗаполнитьЗначенияСвойств(НоваяСтрока, СтрокаИсходнойТаблицы);
КонецЦикла

Для каждой строки исходной таблицы добавляется новая строка в таблицу-получатель и выполняется заполнение значений в тех колонках новой таблицы, имена которых совпадают с именами колонок в исходной таблице

Если у таблиц не будет колонок с одинаковыми именами, таблица-получатель будет в результате содержать столько же строк с пустыми значениями, сколько строк было в таблице-источнике.
Если у каких-то одноименных колонок тип значения данных из таблицы-источника не попадет в массив разрешенных типов колонки таблицы-получателя, в таких полях получим пустые значения.
Рассмотрим третий случай. В случае одноименных колонок колонку таблицы-получателя нужно привести в полное соответствие колонке таблицы-источника.

Полное копирование данных для колонок с совпадающими именами

ОдноименныеКолонки = Новый Массив();

Для Каждого Колонка Из ИсходнаяТаблица.Колонки Цикл
СовпадающаяКолонка = ТаблицаПолучатель.Колонки.Найти(Колонка.Имя);

Если СовпадающаяКолонка <> Неопределено Тогда

// Получить свойства колонки.
Имя = Колонка.Имя;
ТипЗначения = Колонка.ТипЗначения;
Заголовок = Колонка.Заголовок;
Ширина = Колонка.Ширина;

// Заменить колонки в таблице-получателе.
Индекс = ТаблицаПолучатель.Колонки.Индекс(СовпадающаяКолонка);

ТаблицаПолучатель.Колонки.Удалить(Индекс);
ТаблицаПолучатель.Колонки.Вставить(Индекс, Имя, ТипЗначения, Заголовок, Ширина);

// Добавить очередное имя совпадающих колонок в массив.
ОдноименныеКолонки.Добавить(Колонка.Имя);

КонецЕсли;

КонецЦикла;

// Цикл перебора строк исходной таблицы.
Для каждого СтрокаИсходнойТаблицы Из ИсходнаяТаблица Цикл

// Добавить новую строку в таблицу-получатель.
НоваяСтрока = ТаблицаПолучатель.Добавить();

// Заполнить значения в совпадающих ячейках.
Для каждого ИмяКолонки Из ОдноименныеКолонки Цикл
НоваяСтрока[ИмяКолонки] = СтрокаИсходнойТаблицы[ИмяКолонки];

КонецЦикла;

КонецЦикла;

Нам придется заменить колонку в таблице-получателе на новую, чьи свойства полностью будут соответствовать колонке таблицы-источника.
Поэтому в случае обнаружения в таблице-получателе одноименной колонки собираем в переменных все свойства для новой колонки. Далее удаляем старую и создаем новую колонку. Затем выполняем цикл перебора строк исходной таблицы.
В цикле добавляем к таблице-получателю новую строку и открываем цикл перебора имен колонок в массиве совпадающих колонок.
Внутри этого вложенного цикла производим заполнение ячеек таблицы-получателя данными ячейки таблицы-источника.

13. Как добавить колонки к таблице значений «ТаблицаЗначений» с ограничениями по типу?

При добавлении колонки можно просто указать ее имя, а второй параметр метода Добавить() не трогать. В этом случае тип данных колонки – произвольный .

Добавление колонки без указания типа данных

// Добавить колонку без ограничений по типу.
ТаблицаЗначений.Колонки.Добавить("Объект");

Можно заполнить значение второго параметра. Туда необходимо передавать описание разрешенного для колонки типа. Само описание можно получить при помощи конструктора, передав последнему в качестве параметра строковое название типа (если много типов, то через запятую) или массив допустимых типов.

Добавление колонки с указанием типа данных

// Ограничения по типам данных колонки:
// Только элементы справочника "Контрагенты".
ТаблицаЗначений.Колонки.Добавить("Контрагент",Новый ОписаниеТипов("СправочникСсылка.Контрагенты"));

Если среди типов, разрешенных к заполнению данных колонки, есть строка, можно ограничить ее разрядность (длину), указать использование переменной или фиксированной длины. Все это обеспечивается созданием объекта при помощи конструктора КвалификаторыСтроки. Далее этот объект будет использован в качестве одного из параметров конструктора ОписаниеТипов.

Использование квалификаторов для уточнения типа данных колонки таблицы значений

// Подготовка и установка ограничений для данных типа Строка.
КвалификаторыСтроки = Новый КвалификаторыСтроки(20, ДопустимаяДлина.Переменная);
ДопустимыеТипы = Новый ОписаниеТипов("Строка", , КвалификаторыСтроки);
ТаблицаЗначений.Колонки.Добавить("ПримечаниеСтроковоеКороткое", ДопустимыеТипы);

Аналогичные действия можно осуществлять в отношении квалификаторов числа и даты.
Обратите внимание: описание типов можно строить конструктором как «с нуля», так и использовать в качестве основы уже существующее описание типов

Использование существующих описаний типов для указания типа данных колонки таблицы значений

// Расширение уже использованного ранее описания типов.
КвалификаторыЧисла  = Новый КвалификаторыЧисла(10, 2, ДопустимыйЗнак.Неотрицательный);
КвалификаторыДаты = Новый КвалификаторыДаты(ЧастиДаты.Дата);
РасширенныеДопустимыеТипы = Новый ОписаниеТипов(ДопустимыеТипы, "Число, Дата", , КвалификаторыЧисла, , КвалификаторыДаты);

ТаблицаЗначений.Колонки.Добавить("Примечание", РасширенныеДопустимыеТипы);


Оффлайн Admin

  • Администратор
  • *****
  • Сообщений: 260
  • РЕПУТАЦИЯ: 38
  • КПД: 15%
  • Регистрация: 2008-07-10
  • Сайт: forum-1c.ru
  • Профессия: Программист 8.1
Там в списке практически ответ на вопрос есть.
Подпись

Оффлайн Juli1000

  • *
  • Сообщений: 40
  • РЕПУТАЦИЯ: 2
  • КПД: 5%
  • Регистрация: 2009-07-03
  • Сайт: 
Спасибо большое))


Теги:
 


* Живое общение

Не устроил ответ?

Зарегистрируйся и задай свой вопрос. Живое общение приносит результат намного быстрее.


Зарегистрироваться

* Реклама

* Поиск

* Последние задачи на разработку (фриланс)

* Реклама

* Последние вакансии

* Топ 10 авторов за месяц

Геннадий ОбьГЭС Геннадий ОбьГЭС
133 Сообщений
AIFrame
73 Сообщений
alex0402
52 Сообщений
ilyay ilyay
51 Сообщений
andron81_81
44 Сообщений
oleg-x
35 Сообщений
MuI_I_Ika MuI_I_Ika
31 Сообщений
BuhRust
30 Сообщений
Golickoff Golickoff
27 Сообщений
alexandr_ll
23 Сообщений

* Кто онлайн

  • Точка Гостей: 222
  • Точка Скрытых: 0
  • Точка Пользователей: 5
  • Точка Сейчас на форуме:

* Облако тэгов

* Форум 1С с мобильного

* Инструменты

* Дополнительно

Поиск

 
SimplePortal 2.3.5 © 2008-2012, SimplePortal