Срез последних цен

[astronavt]

Добрый день! Делаю отчёт по продажам продукции. Не получается сделать срез последних цен на дату продажи. Подскажите в чём может быть дело. Вот мой запрос

ВЫБРАТЬ
ПродажиОбороты.КоличествоОборот,
ПродажиОбороты.СтоимостьОборот КАК СтоимостьОборот,
ЦеныНоменклатурыСрезПоследних.Цена,
ЦеныНоменклатурыСрезПоследних.ЕдиницаИзмерения,
ПродажиОбороты.Номенклатура,
ЦеныНоменклатурыСрезПоследних.ТипЦен,
ПродажиОбороты.Организация
ИЗ
РегистрНакопления.Продажи.Обороты(&НачалоПериода, &КонецПериода, День, ) КАК ПродажиОбороты
ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры.СрезПоследних(&КонецПериода, ) КАК ЦеныНоменклатурыСрезПоследних
ПО ПродажиОбороты.Номенклатура = ЦеныНоменклатурыСрезПоследних.Номенклатура
ГДЕ
(НЕ ПродажиОбороты.Номенклатура.Услуга)

[has]

Это не подойдет? http://www.kb.mista.ru/article.php?id=92

Срез последних на каждую дату в запросе

Срез последних на каждую дату в запросе

Получение актуальных данных из регистра сведений на дату, получаемую в самом запросе

Автор статьи: Rovan | Редакторы: Гений 1С, acsent, Defender aka LINN, Asmody, BabySG, ILM, Schwomulurn, АЛьФ, Vladal, Волшебник, Gimalaj Последняя редакция №29 от 12.08.19 | История URL: http://kb.mista.ru/article.php?id=92

Ключевые слова: СрезПоследних, внутри, запрос, периодический, регистр сведений

Эта статья перенесена в Книгу знаний v.2 http://wiki.mista.ru/doku.php?id=1c:v8:srez_poslednix_na_kazhduju_datu_v_zaprose

Существует несколько способов получить нужные данные.

Непосредственно в запросе

Способ подходит практически для любой ситуации и поэтому наиболее универсален. Единственный,
пожалуй, минус этого способа - если в отчете пользователю не требуется курс, то запрос будет
выбирать избыточные данные.

Вызов СрезПоследних() можно использовать только с передачей в него заранее готового значения даты,
на которую требуется получить значения. Поэтому сабж делается через стыковку нескольких запросов -
основной, к нему стыкуется запрос по регистру сведений с условием по дате и поиском записи с
маскимальной датой (периодом).


ВЫБРАТЬ
Таб1.СсылкаДок,
Таб1.ДатаДок,
Таб1.ВалютаДок,
Таб2.Курс
ИЗ
(ВЫБРАТЬ
ЗаказПокупателя.Ссылка КАК СсылкаДок,
ЗаказПокупателя.Дата КАК ДатаДок,
ЗаказПокупателя.ВалютаДокумента КАК ВалютаДок,
МАКСИМУМ(Валюты.Период) КАК ПериодДок
ИЗ
Документ.ЗаказПокупателя КАК ЗаказПокупателя
ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.КурсыВалют КАК Валюты
ПО Валюты.Период <= ЗаказПокупателя.Дата И
Валюты.Валюта = ЗаказПокупателя.ВалютаДокумента
СГРУППИРОВАТЬ ПО
ЗаказПокупателя.Ссылка) КАК Таб1
ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.КурсыВалют КАК Таб2
ПО Таб1.ПериодДок = Таб2.Период И Таб1.ВалютаДок = Таб2.Валюта



В 8.1. вместо обращения к курсам валют удобнее и надежнее использовать временную таблицу с нужными
датами, потому что не во всех организациях ведут курсы валют ежедневно. ;-)

Для общего развития:
Что есть срез последних в платформе?


ВЫБРАТЬ
Рег.Период,
Рег.Измерение,
Рег.Ресурс
ИЗ
РегистрСведений.ПериодическийРегистр.СрезПоследних(&Дата) КАК Рег


В зависимости от периодичности регистра (по времени, по позиции регистратора) ВТ разворачивается в
следующий запрос:
1. По времени (год, месяц, ... секунда)

ВЫБРАТЬ
Таблица3.Ресурс,
Таблица3.Измерение,
Таблица3.Период
ИЗ
(ВЫБРАТЬ
Таблица1.Измерение КАК Измерение,
МАКСИМУМ(Таблица1.Период) КАК Период
ИЗ
РегистрСведений.ПериодическийРегистр КАК Таблица1
ГДЕ
Таблица1.Период <= &Дата
СГРУППИРОВАТЬ ПО
Таблица1.Измерение) КАК Таблица2
ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ПериодическийРегистр КАК Таблица3
ПО Таблица2.Измерение= Таблица3.Измерение
И Таблица2.Период = Таблица3.Период



2. По позиции регистратора
В данном случае нужно еще раз обернуть выборку


ВЫБРАТЬ
Таблица5.Ресурс,
Таблица5.Измерение,
Таблица5.Период,
Таблица5.Регистратор
ИЗ
(ВЫБРАТЬ
МАКСИМУМ(Таблица3.Регистратор) КАК Регистратор,
Таблица3.Измерение
ИЗ
(ВЫБРАТЬ
Таблица1.Измерение КАК Измерение,
МАКСИМУМ(Таблица1.Период) КАК Период
ИЗ
РегистрСведений.ПериодическийРегистр КАК Таблица1
ГДЕ
Таблица1.Период <= &Дата
СГРУППИРОВАТЬ ПО
Таблица1.Измерение) КАК Таблица2
ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ПериодическийРегистр КАК Таблица3
ПО Таблица2.Измерение= Таблица3.Измерение
И Таблица2.Период = Таблица3.Период
СГРУППИРОВАТЬ ПО
Таблица3.Измерение) КАК Таблица4
ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ПериодическийРегистр КАК Таблица5
ПО Таблица4.Измерение = Таблица5.Измерение
И Таблица4.Регистратор = Таблица5.Регистратор
И Таблица4.Период= Таблица5.Период // Если документ делает два и более движения в разных
периодах!


Все это можно увидеть посмотрев технологический журнал с включенным режимом протоколирования
запросов

Система компоновки данных

Данный способ подходит для отчетов. Из очевидных плюсов - если курс (или другие данные) не нужны для
построения отчета, то СКД не будет их получать. Однако быстродействие такого отчета может оказаться
и несколько ниже, чем в первом способе.

Для примера сделаем отчет - список заказов покупателей.

Для этого создадим набор данных "Документы" - запрос:


ВЫБРАТЬ
ЗаказПокупателя.Ссылка КАК ЗаказПокупателя,
ЗаказПокупателя.Дата КАК Дата,
ЗаказПокупателя.ВалютаДокумента КАК ВалютаДокумента,
ЗаказПокупателя.СуммаДокумента КАК СуммаДокумента
{ВЫБРАТЬ
ЗаказПокупателя.*,
Дата,
ВалютаДокумента.*,
СуммаДокумента}
ИЗ
Документ.ЗаказПокупателя КАК ЗаказПокупателя
{ГДЕ
ЗаказПокупателя.Ссылка.* КАК ЗаказПокупателя,
ЗаказПокупателя.СуммаДокумента}


Для того, чтобы потом успешно связать наборы данных, в запрос необходимо включить поля "Дата" и
"ВалютаДокумента". Чтобы они не появлялись в списке доступных полей, если это необходимо, их можно
убрать, установив флажки ограничений в таблице "Поля" схемы компоновки. В остальном запрос вряд ли
требует комментариев.
<IMG SRC="files/">http://defender_aka_linn.users.photofile.ru/photo/defender_aka_linn/150041386/154871726.jpg</IMG>

Для того, чтобы получить информацию о курсах валют, добавим второй набор данных - запрос "Курсы
валют":


ВЫБРАТЬ
&Дата КАК Дата,
КурсыВалютСрезПоследних.Валюта КАК Валюта,
КурсыВалютСрезПоследних.Курс КАК Курс,
КурсыВалютСрезПоследних.Кратность КАК Кратность
{ВЫБРАТЬ
Дата,
Валюта.*,
Курс,
Кратность}
ИЗ
РегистрСведений.КурсыВалют.СрезПоследних(&Дата, Валюта = &Валюта) КАК
КурсыВалютСрезПоследних
{ГДЕ
КурсыВалютСрезПоследних.Курс,
КурсыВалютСрезПоследних.Кратность}


В этом запросе имеются 2 параметра: "Дата" и "Валюта". Эти параметры будут установлены СКД при
соединении наборов. Кроме того, параметр "Дата" указан в выбранных полях - это нужно для соединения
таблиц.
В этом запросе необходимо отключить галочку "Автозаполнение".
Для ненужный полей "Дата" и "Валюта" также устанавливаем флажки ограничений, чтобы они не появлялись
в доступных полях.
<IMG SRC="files/">http://defender_aka_linn.users.photofile.ru/photo/defender_aka_linn/150041386/154871728.jpg</IMG>

Перейдем к соединению наборов. На странице "Связи наборов данных" добавим 2 связи:
1. Источник связи - набор "Документы", приемник - набор "Курсы валют". Выражение источник - "Дата",
выражение приемник - "Дата", Параметр - "Дата"
2. Источник связи - набор "Документы", приемник - набор "Курсы валют". Выражение источник -
"ВалютаДокумента", выражение приемник - "Валюта", Параметр - "Валюта"
<IMG SRC="files/">http://defender_aka_linn.users.photofile.ru/photo/defender_aka_linn/150041386/154871729.jpg</IMG>

Главное здесь - параметры связи. При соединении наборов данных, если указан параметр, СКД передает в подчиненный набор (в нашем случае - запрос "Курсы валют") параметры, указанные в соединении.
Значениями параметров будут значения соответствующих полей набора-источника.

Перейдем к вычисляемым полям. Добавим вычисляемое поле "СуммаВВалютеУпрУчета". Выражение поля - "СуммаДокумента * Курс / Кратность".
<IMG SRC="files/">http://defender_aka_linn.users.photofile.ru/photo/defender_aka_linn/150041386/154871876.jpg</IMG>

Также укажем поля "СуммаДокумента" и "СуммаВВалютеУпрУчета" как ресурсы
<IMG SRC="files/">http://defender_aka_linn.users.photofile.ru/photo/defender_aka_linn/150041386/154871877.jpg</IMG>

Настроим отчет.
Добавим одну группировку "Детальные записи", в выбранных полях укажем "ЗаказПокупателя", "Курс" и
"Кратность". Добавим ресурсы "СуммаДокумента" и "СуммаВВалютеУпрУчета"
<IMG SRC="files/">http://defender_aka_linn.users.photofile.ru/photo/defender_aka_linn/150041386/154871878.jpg</IMG>

Можно формировать отчет
<IMG SRC="files/">http://defender_aka_linn.users.photofile.ru/photo/defender_aka_linn/150041386/154871880.jpg</IMG>

[astronavt]

Это не подойдет? http://www.kb.mista.ru/article.php?id=92

Я это уже читал((( подобное делаю у себя - не получается.

[ivanov660]

Вам надо получше разобраться с запросами, к примеру, РегистрНакопления.Продажи.Обороты(&НачалоПериода, &КонецПериода, День, НЕ Номенклатура.Услуга ). Запрос более сложный. Надо выбрать срез на дату документа, а не на &КонецПериода.